第１回昔のＰＣ板杯ﾌﾟﾛｸﾞﾗﾑｺﾝﾃｽﾄ

1 ：あまぐらまぁ：01/12/20 20:21.net

毎年恒例となった 第１回昔のＰＣ板杯ﾌﾟﾛｸﾞﾗﾑｺﾝﾃｽﾄを開催するヨ！
かつてやった（であろう）ｸﾀﾞﾗﾈｰ!!プログラムや ｸﾀﾞﾗﾈｰ!!テクニックを
再びここで披露して下さい。

目的：画面上に１００回「ｵﾏｴﾓﾅｰ」と表示させる。
　　　特例としてカナが使えない機種は「OMAEMONA-」でも良い。
使用機種：不問
使用言語：ＢＡＳＩＣ限定（各機種の方言の使用は可）
条件：プログラムコードが長くならないように注意。
　　　（省略されました・・全てを読むにはここを押してください）が
　　　出てしまったら、そのエントリーは無効。
評価：綺麗なソースやアルゴリズムだけではなく、実行したときの芸術性
　　　なども評価の対象とする。
　　　表示１回毎に色を変えたり音を出したり等、演出を凝らすのは
　　　構わない。各自工夫してプログラムすること。
　　　ネタ歓迎！。

エントリーする人は、動作機種を（ものによっては何ＢＡＳＩＣかも）明記してくれ。
エントリーに対するレスなんかも大いにしちゃって！。もりageて行こう！
ﾋﾞｸｰﾘするようなヤツ期待してます！

43 ：ナイコンさん：01/12/22 17:26.net

SHARP BASIC SP-50X0の場合。

LIST
10 PRINT"Ｃ":J=53248:FORI=1TO100
20 POKEJ,166:J=J+1:POKEJ,138:J=J+1:POKEJ,165:J=J+1:POKEJ,141:J=J+1
30 POKEJ,149:J=J+1:POKEJ,191:J=J+1:POKEJ,207:J=J+1:NEXT
READY
DATA ERROR
READY
■

10行の「Ｃ」はリバース文字。(画面消去文字)
１行80カラムの制限がある。
実行すると、画面の左上から、「ｵﾏｴﾓﾅｰ」と顔キャラクタを100回表示する。
各文字は、ASCIIコードとは別系統の「ディスプレイコード」。
「DATA ERROR」の表示は、直前の「READY」でCRキーを押した時に出るお約束。
　MicrosoftBASICで言うところの「Out Of Data」。

44 ：名無しさん＠Ｒ８００：01/12/22 17:33.net

>>41
30行目の後ろのprint文はスペース６個です。失礼しました。

45 ：ナイコンさん：01/12/22 17:37.net

スペースは全角て

46 ：ナイコンさん：01/12/22 18:50.net

5 DIM A$(99):gosub *read
10 A=int(rnd*15)
20 B=int(rnd*15)
30 C=3+int(rnd*15)
40 if int((A-1)/3)=(A-1)/3 then 50 else 10
50 if int((B-2)/3)=(B-2)/3 then 60 else 20
60 if int(C/3)=C/3 then 120 else 30
120 print A$(A);A$(B);A$(C)
130 goto 10
150 *read
160 I=1
170 read A$(I)
180 if A$(I)="逝ってよし" then return
190 I=I+1
200 goto 170
210 DATA ネオ麦茶が,九州で,西鉄バスを乗っ取った,ラディンが,ニューヨークで,ビルを破壊した
220 DATAオウムが,地下鉄日比谷線で,サリンをぶちまいた,キャットキラーが,一人で暴言はにゃ〜んスレッドで,1000をとれなかった
230 DATA 埼玉の学生が,WinMXで,逮捕された,ひろゆきが,自宅で,警察に押し掛けられる,逝ってよし

47 ：ナイコンさん：01/12/22 18:55.net

5 data a,b,c,d,e,f,g,h,i,j,k,l,m,n,o,p,q,r,s,t,u,v,w,x,y,z,
10 cls 3:color 7:width 100,30
20 dim a$(25):dim k(80):i=0:ii=0:s=80:ki=1
30 for a=1 to 26
40 read a$(i):I=i+1
50 next a
100 for k=0 to s
110 r=rnd*27
115 if r=>25 then goto 110 else goto 116
116 'print r
120 k(ii)=r:ii=ii+1
130 next k
140 for j=1 to s
150 locate j-1,y:color 4:print a$(k(j));
160 next j
200 'key
210 ke$=inkey$:if ki>80 then i=1:ki=1:ii=0:y=y+2:goto 100
220 if ke$="" then 210
230 if ke$=a$(k(ki)) then locate ki-1,y+1:color 5:print a$(k(ki));:ki=ki+1:beep:goto 210:else locate ki-1,y+1: color 2:print ke$:color 7:beep:goto 210
215 line (ki*8-8,y*16)-(ki*8,y*16+32),6,b

48 ：47：01/12/22 19:01.net

width 100,30は80,25の間違い・・無くてもよし。

49 ：大学生MSXユーザ@(3 AND 23)：01/12/22 19:36.net

>>40

>>23の動作解説してみます。
SCREEN0だと、VRAMの０番地からが画面に表示している
文字の文字コードが入ってます。
で、VRAMの0番地からに対応する個所に「ｵﾏｴﾓﾅｰ」と書いて（10行）、
残りの「ｵﾏｴﾓﾅｰ」はループまわして（20行）最初に書いた所から
文字コードを拾ってきてコピペ（30行）します。
そのときに文字色をいじることで（20行）ちょっと表示を派手にしてます。

>>3の解説いりますか？

とまぁ、解説だけではアレなんでもう1個。

動作機種：MSX（多分全機種（動作未確認））

10 'A ｰﾅﾓｴﾏｵ A
20 FORAD=32768TO32800:IFPEEK(AD)=65THEN30ELSENEXT
30 TP=AD+1:FORAD=TPTO32800:IFPEEK(AD)=65THEN40ELSENEXT
40 ED=AD-1:FORI=1TO100:FORAD=EDTOTPSTEP-1
50 PRINT CHR$(PEEK(AD));NEXT:NEXT

50 ：大学生MSXユーザ@(3 AND 23)：01/12/22 19:37.net

>>49
ぐはぁ、誤植ﾊｹｰﾝ

50行は↓こうです。
50 PRINT CHR$(PEEK(AD));:NEXT:NEXT

51 ：25：01/12/22 21:42.net

>>42
ああ、やっぱりそれで良かったですか。
LISTの文法がうろ覚えだったので、"LIST"だけにしておきました。

ところで、N60-BASICでは、プログラム中に"LIST"があると、
後に何があろうと、リストを表示した時点でプログラムが終わってしまったんですが
他のマシンでもそうだったんでしょうか？

52 ：ナイコンさん：01/12/22 22:41.net

オーソドックスなBASICプログラム。

10 LET A = 0
20 LET A = A + 1
30 IF A = 100 THEN GOTO 100
40 PRINT "OMAEMONA-　";
50 GO TO 20
100 STOP
110 END

53 ：ナイコンさん：01/12/22 22:45.net

>>51

Hu-BASIC系は、

10 LIST:RUN

が正常に実行できたと思う。

54 ：ナイコンさん：01/12/22 23:07.net

>>53
X1ではダメだったような記憶がありますが、
間違ってるかも。。。

55 ：25：01/12/22 23:25.net

ちょっと脱線したのでネタ振った責任をとってひとつ

PC-6001 N60-BASIC

10 REM *** ｼﾞﾝｺｳﾑﾉｳ ｵﾏｴﾓﾅｰ ***
20 CLS
30 FOR I=1 TO 100
40 INPUT A$
60 PRINT ">>";A$
70 PRINT "ｵﾏｴﾓﾅｰ"
80 NEXT

56 ：ナイコンさん：01/12/23 00:20.net

>>55にﾜﾗﾀ
勝手に改造

PC-6001 N60-BASIC

10 REM *** ｼﾞﾝｺｳﾑﾉｳ ｵﾏｴﾓﾅｰ ｼﾞﾄﾞｳ　ｼﾞｻﾞｸｼﾞｴﾝ***
20 CLS
30 FOR I=1 TO 100
40 INPUT A$
50 PRINT I*2-1;"ﾅﾏｴ:ﾅｲｺﾝｻﾝ　ﾄｳｺｳﾋﾞ:";DATE$;" ";LEFT$(TIME$,5)
51 PRINT "　　　　";A$
55 PRINT I*2;"ﾅﾏｴ:ﾅｲｺﾝｻﾝ　ﾄｳｺｳﾋﾞ:";DATE$;" ";LEFT$(TIME$,5)
60 PRINT "　　　　>>";A$
70 PRINT "　　　　ｵﾏｴﾓﾅｰ"
80 NEXT

57 ：ナイコンさん：01/12/23 00:38.net

>>56
いいアイデアだけど
Ｎ６０−ＢＡＳＩＣにはＤＡＴＥ＄、ＴＩＭＥ＄はないよ。

どっちっかつーっと、Ｎ−ＢＡＳＩＣかな？

58 ：56：01/12/23 00:51.net

あららしまった。
うちのはN88でした・・・

59 ：ナイコンさん：01/12/23 02:04.net

高校生の頃、こんな感じのプログラムを作ったことがある。
で、DISK-BASICで自動起動

PC-9801 N88-BASIC

10 WIDTH 80,25:CLS
20 F=0:A$="■":X=0:Y=3:C=0
30 PRINT "NFC OMAEMONA-BASIC"
40 PRINT "Copyright(C) Micro$oft云々"
50 PRINT "Ok"
60 LOCATE X,Y:PRINT A$;
70 F = F + 1
80 IF F = 100 AND A$ = "■" THEN A$="　":F=0
90 IF F = 100 AND A$ = "　" THEN A$="■":F=0
100 B$=INKEY$
110 IF B$="" GOTO 60
120 IF ASC(B$) > 31 THEN LOCATE X,Y:PRINT B$;:X=X+1:IF X>79 THEN X=0:Y=Y+1
130 IF ASC(B$) = 13 THEN 150
140 GOTO 60
150 LOCATE X,Y:PRINT " ":PRINT "?ｵﾏｴﾓﾅｰ Error":PRINT "Ok":C=C+1
160 ＩＦ C = 100 THEN END
170 X=0:Y=Y+3
180 IF Y > 23 THEN Y=23:PRINT
190 GOTO 60

記憶を頼りに適当に書いたので、バグ在中かも。特にスクロール関連。
80-90行のFの判定は、カーソルの点滅のタイミングに合わせて適当に変更。

60 ：59：01/12/23 02:10.net

>>559
120行でYが増えたあとYのチェックをしてないじゃん。

120 IF ASC(B$) > 31 THEN LOCATE X,Y:PRINT B$;:X=X+1:IF X>79 THEN X=0:Y=Y+1:IF Y > 23 THEN Y=23:PRINT

61 ：59：01/12/23 02:11.net

559→59だし・・・鬱

62 ：旧機種に優しい。ともちん：01/12/23 02:27.net

>>54
今、X1エミュ＋Hu-Basic1.0で試したら通ったYO!

63 ：59：01/12/23 02:43.net

すまない。
>>33のN88互換BASICで試してみたら、バグがあったのでさらに修正

120 IF ASC(B$) > 31 THEN LOCATE X,Y:PRINT B$:X=X+1:IF X > 79 THEN X=0:Y=Y+1:IF Y>23 THEN Y=23:PRINT;

64 ：ナイコンさん：01/12/24 01:20.net

PC-9801 N88-BASIC

100 WIDTH 80,25:CLS
110 X=70
120 FOR I=1 TO 100
130 FOR J=1 TO 7
140 B=X+J
150 IF B > 79 THEN B=B-79
160 Y = 12 - SIN(B*10*3.14/180)*10
170 LOCATE B,Y:PRINT MID$("ｵﾏｴﾓﾅｰ ",J,1);
180 NEXT
190 X=X-1:IF X < 0 THEN X=79
200 FOR J=0 TO 50:NEXT
210 NEXT

サインカーブを描いて"ｵﾏｴﾓﾅｰ"が移動します。

65 ：環境(config,sys?)に優しい。ともちん：01/12/24 01:24.net

>>64
速すぎるので、適当なウェイトを入れたほうがいいかも？

66 ：ナイコンさん：01/12/24 16:14.net

こうしてみると、不思議とN88派が多いな。

67 ：ナイコンさん：01/12/24 18:46.net

>>66
9801を通ってきてる人は多いからね。
N60でやりたいんだけど検証環境がない。

68 ：ナイコンさん：01/12/24 18:58.net

無料のN88互換BASIC for windows
テキストファイルにコピペするだけで動くから楽だYO!

http://www2s.biglobe.ne.jp/~yamadai/

69 ：ナイコンさん：01/12/24 19:00.net

>>68
よくマイクロソフトに訴えらんねーな(w

70 ：ナイコンさん：01/12/24 19:16.net

>>69
別にソース丸写しじゃなきゃ問題ないでしょ？
ただの移植プログラムなんだし

71 ：ナイコンさん：01/12/24 19:24.net

>>70
コードの一部分やロジックも全く流用していれば問題ないと思われ。
で流用してないの？

72 ：ナイコンさん：01/12/24 19:27.net

>>69
言語に著作権があると思ってる人ﾊｹｰﾝ

73 ：ナイコンさん：01/12/24 19:27.net

ロジックも流用していれば→ロジックを流用していなければ

74 ：ナイコンさん：01/12/24 19:29.net

>>72
厨房を発見しました！
これより迎撃体制に入ります。

75 ：ナイコンさん：01/12/24 19:36.net

>>69-74
別スレでやってちょうだい。

76 ：ナイコンさん：01/12/24 19:38.net

>>75
オマエモナ

77 ：ナイコンさん：01/12/25 00:31.net

>>56をさらに勝手に改造

N88-BASIC
10 REM *** ｼﾞﾝｺｳﾑﾉｳ ｵﾏｴﾓﾅｰ ｼﾞﾄﾞｳ　ｼﾞｻﾞｸｼﾞｴﾝ v1.1 ***
20 CLS
30 DIM A$(5)
40 C=0
50 FOR I=1 TO 5
60 READ A$(I)
70 NEXT
80 INPUT B$
90 PRINT 1;" ﾅﾏｴ:ﾅｲｺﾝｻﾝ　ﾄｳｺｳﾋﾞ:";DATE$;" ";LEFT$(TIME$,5)
100 PRINT "　　　　";B$
110 FOR I=2 TO 1000
120 R=INT(RND(1)*5)+1:IF 1001-I=100-C THEN R=1
130 IF C=100 THEN R=INT(RND(1)*4)+2
140 PRINT I;" ﾅﾏｴ:ﾅｲｺﾝｻﾝ　ﾄｳｺｳﾋﾞ:";DATE$;" ";LEFT$(TIME$,5)
150 PRINT " >>";I-1
160 PRINT "　　　　";A$(R)
170 IF R=1 THEN C=C+1
180 NEXT
190 PRINT " 1001 ﾅﾏｴ:1001　ﾄｳｺｳﾋﾞ:Over 1000 Thread"
200 PRINT "　　　　ｺﾉｽﾚｯﾄﾞﾊ1000ｦｺｴﾏｼﾀ"
210 PRINT " ﾓｳｶｹﾅｲﾉﾃﾞ ｱﾀﾗｼｲｽﾚｯﾄﾞｦﾀﾃﾃｸﾀﾞｻｲ"
220 END
230 DATA "ｵﾏｴﾓﾅｰ","ｲｯﾃﾖｼ","ﾊｧﾊｧ","ﾊｹﾞｼｸﾄﾞｳｲ","ﾜﾗﾀ"

ちゃんと"ｵﾏｴﾓﾅｰ"は100回表示されるはず。

78 ：ナイコンさん：01/12/25 00:52.net

>>25
思わず吹き出してツバをモニタに飛ばした（藁
続いて26から見ます

79 ：大学生MSXユーザ@(3 AND 23)：01/12/25 01:47.net

使用機種：MSX（多分何処の国のマシンでもOK）

10 DATA "00043e0c14142400"
20 DATA "00f71212a2422f00"
30 DATA "007c117c10108d00"
40 DATA "0040e0405c800000"
50 SCREEN1:WIDTH32:CLS
60 FORI=0TO99:PRINT"ABCD";:NEXT
70 TIME=0:FORI=0TO600:I=TIME:NEXT
80 FORC=65TO68:READA$:FORI=0TO7
90 N=VAL("&H"+MID$(A$,I*2+1,2))
99 VPOKE 8*C+I,N:NEXT:NEXT

80 ：ナイコンさん：01/12/25 01:52.net

SP-5030のカーソル移動記号などはどう表記したものかな〜。

81 ：ナイコンさん：01/12/25 21:06.net

お前モナーでキータッチ　半角全角ひらカタランダムです
N88互換BASIC　全機種OKだと思う。
10 data お,オ,ｵ,ま,マ,ﾏ,え,エ,ｴ,も,モ,ﾓ,な,ナ,ﾅ,ー,ｰ,-,お前モナー
20 I=0:dim A$(99):cls
30 read A$(I)
40 if A$(I)="お前モナー" then 60
50 I=I+1:goto 30
60 I=0:for K=1 to 6
70 R=int(rnd*5)
80 if R>2 then 70
90 Q$=Q$+A$(I+R)
100 I=I+3
110 next K
120 color 5:print Q$
130 line input Y$
140 if Y$=Q$ then color 4:print"(・∀・）ｲｲ":Q$="":goto 60 else color 2:print "違うぞゴルァもう一回打て！":color 5:goto 130

82 ：ナイコンさん：01/12/25 21:08.net

>>79
MSXはよく分からないけど、"ABCD"のフォントを書き換えて
"ｵﾏｴﾓﾅｰ"を表示してるってことでいいのかな?

久しぶりに16進をドット絵変換したよ。

83 ：ナイコンさん：01/12/25 21:53.net

>>81
昔ってことでカナ入力タイピングゲームもよかろう。

N88-BASIC

10 COLOR 7:CLS
20 A$="ｵﾏｴﾓﾅｰ":B$="6j5mu-"
30 T$=TIME$:E=0:LOCATE 31,12:PRINT A$;
40 FOR I=1 TO 100
50 FOR J=1 TO 6
60 COLOR 2:LOCATE 30+J,12:PRINT MID$(A$,J,1);
70 C$=INKEY$
80 IF C$="" THEN 70
90 IF C$<>MID$(B$,J,1) THEN BEEP:E=E+1:GOTO 70
100 COLOR 7:LOCATE 30+J,12:PRINT MID$(A$,J,1);
110 NEXT
120 PRINT I
130 NEXT
140 PRINT "START ";T$
150 PRINT "END ";TIME$
160 PRINT "MISS ";E

CapsLockはオフの方向で。

84 ：大学生MSXユーザ：01/12/25 22:38.net

>>82
そうです。

・・・なんか俺ばっかり書いてるような気がする。
鬱だ。

＃MSX-BASIC、N88-BASIC以外のBASICのコードｷﾎﾞﾝﾇ>oll

85 ：JOY ◆chesX68k ：01/12/26 03:54.net

しばらく留守にしてたけど、このスレ盛り上がってたんで安心したｰﾖ。
さすが２chらしい面白いアイディアの方向に発展してて、これからが
楽しみやねー。奇抜なのをボシュー!!。

>>84さんの言う通り、「読めﾈｰﾖ!!」級の機種依存バリバリなプログラム
見てみたいですわ。

っていうか、勝手に仕切ってるみたいでスマソ。

86 ：X1F：01/12/26 09:01.net

X1用 Hu-BASCI (V1 or V2)
10 J=0:GOTO 1000
999 END
1000 CLS:FOR I=10 to 100 STEP 10:PRINT J+I;" PRINT ";CHR$(32);"オマエモナー";CHR$(32):NEXT
1010 J=J+1:if(J=10) then PRINT "RUN" else "GOTO 1000"
1020 KEY 0,STRING$(10,11)

動作確認していないので、動くかどうか不安ですが。

87 ：86：01/12/26 09:40.net

>>86
1020行にバグ発見。正しくは、
1020 LOCATE 0,0:KEY 0,STRING$(10,11)
です。

88 ：ナイコンさん：01/12/26 10:27.net

N60BASIC （"□"はスペース）他機種移植も容易だと思います。

1 CLS:S=0:T=0
2 FOR L=1 TO 5:LOCATE 0,L:PRINT L;":";:X(L)=20:NEXT L
3 LOCATE 0,0:INPUT "よそう□1-5";Y
4 FOR L=1 TO 100
5 R=INT(RND(1)*5)+1:X=X(R):IF X<=0 THEN 5
6 X=X-1:LOCATE X+2,R:PRINT "オマエモナー□";
7 IF X<=0 THEN S=S+1:PRINT S;"ちゃく";:IF S=1 THEN T=R
8 X(R)=X:FOR M=1 TO 1:NEXT M
9 NEXT L:LOCATE 0,7:PRINT "かち=";T;"□";
10 IF T=Y THEN PRINT "あたり!!大金もち!":GOTO 12
11 PRINT "はずれ!!大びんぼう!"
12 PRINT:INPUT "もういちど□やる?(Y/N)";Y$
13 IF Y$="Y" OR Y$="Y" THEN 1
14 END

89 ：88：01/12/26 10:34.net

あう、88の13行にバグ発見(T_T)
13 IF Y$="Y" OR Y$="y" THEN 1
です。

90 ：ナイコンさん：01/12/26 14:29.net

>>88
"大金"もち、"大"びんぼうにやられた。

91 ：ナイコンさん：01/12/26 16:32.net

N88-BASIC(86)一応実機で確認済

10 screen 3,0:cls 3
20 for a=1 to 100
30 restore
40 for b=1 to 16
50 read x1,y1,x2,y2
60 line (x1,y1)-(x2,y2),7
70 next
80 roll 20
90 next
100 rem ---------------------------------------------
110 data 0,385,19,385, 10,380,10,399, 10,385,0,399
120 data 20,390,30,399, 20,380,38,380, 39,380,25,395
130 data 40,381,58,381, 50,381,50,399, 40,399,58,399
140 data 60,381,78,381, 60,390,78,390, 70,381,70,399, 70,399,78,399
150 data 80,385,99,385, 90,381,80,399
160 data 100,390,639,390

92 ：ナイコンさん：01/12/26 16:43.net

WHILE 1:PRINT"ﾃｲｺｸﾊﾞﾝｻﾞｲ　";:WEND

93 ：シトラス ◆TCUoE/5Q ：01/12/26 17:28.net

>>33
そのN88互換BASICの作者ってσ(▼▼;)おれの高校の時の数学の先生だったんだよなぁ
いや、ﾏﾁﾞで
東工大から富士通かどっかのプログラマやって教師になったらすぃ
エクセルのマクロで高校の図書館の蔵書管理システムつくってたなぁ
パソコンにバーコードリーダーつなげて…
大量の本にバーコード貼るの大変だったなぁ

94 ：大学生MSXユーザ：01/12/26 19:33.net

新作です。
使用機種：MSX２以降

10 SCREEN 5:PSET(0,1):FORI=0TO1
20 READ A$:IF A$="ｱﾎﾞｰﾝ"THEN 40
30 I=0:DRAW A$:NEXT
40 COPY (0,0)-(143,7) TO (36,0)
50 COPY(0,0)-(200,170)TO(0,9)
60 A$=INPUT$(1)
100 DATA "R4D3L2DLD2U2RUR2D3U7D"
110 DATA "R8D3L4UDRDRDRD"
120 DATA "R7L2U5L2R8"
130 DATA "L2U2L2R4L2D7R6"
140 DATA "URU2RU4D2L3R6"
150 DATA "DR5","ｱﾎﾞｰﾝ"

95 ：ナイコンさん：01/12/26 20:07.net

　か

96 ：ナイコンさん：01/12/26 20:08.net

Abort
Ready

97 ：イブニング256：01/12/26 23:13.net

10 'ﾀｲﾄﾙ ﾌﾞﾗｸﾗ 　ﾀｲｵｳｷｼｭ N88BASIC,N88ｺﾞｶﾝBASIC
20 A=int(rnd*800)
30 B=int(rnd*600)
40 C=int(rnd*10)
50 AA=int(rnd*800)
60 BB=int(rnd*600)
70 if C>7 then 40
80 line(A,B)-(AA,BB),C,BF
90 for o=1 to 10
100 D=int(rnd*100)
110 E=int(rnd*30)
120 if D>80 or E>25 then 100
130 locate D,E:color C:print "ｵﾏｴﾓﾅｰ":next o
140 goto 20

98 ：MZ-1500：01/12/28 12:05.net

10 CLS
20 DIM C$(9)
30 FOR I=0 TO 16:READ C$(I):NEXT I
40 MN=0
50 CC=INT(RND(1)*7)+1:CR=INT(RND(1)*17)
60 COLOR CC,0:PRINT C$(CR);
70 IF CR=0 THEN MN=MN+1
80 IF MN<100 THEN 50
90 END
100 DATA "ｵﾏｴﾓﾅｰ ","ｲｯﾃﾖｼ ","ﾏﾀｰﾘ ","ｻﾗｼage ","（ﾜﾗ ","（・ｗ・）V "
110 DATA ">>1ｻｰﾝ! ","ﾔﾒﾚ ","ｳﾌﾟ ｷﾎﾞﾝﾇ ","ｱﾎﾞｰﾝ ","（＞ω＜)Σｶﾞｰﾝ "
120 DATA "(・∀・）ｲｲ ","ﾜｼｮｰｲ ","(ﾌﾟ ","2ﾁｬﾝﾈﾗ ","DO-YO! ","ｻｲｺｰ "


:FOR I=1 TO 100:PRINT"ｵﾏｴﾓﾅｰ";:NEXT I:END


1行プログラム

99 ：MZ-1500：01/12/28 12:24.net

>>98
ﾌﾟﾛｸﾞﾗﾑにﾊﾞｸﾞは憑き物である。
ﾌﾟﾛｸﾞﾗﾑを打ち込んだあと充実感に浸りながらRUN！ﾋﾟｰ！ｶﾞｯｸｰﾝ、ﾅﾇｰ、ｵﾉﾚ!
この脱力感と怒りがたまらんのね。

20行目C$(9)→C$(16)でした。

以下は消し忘れでした（爆
1行プログラム
10 FOR I=1 TO 100:PRINT"ｵﾏｴﾓﾅｰ";:NEXT I:END
ｽﾏｿ

100 ：100：01/12/29 00:15.net

100 GET A,G,E

101 ：ＮＰＣさん：01/12/29 09:25.net

101 DELETE 100

102 ：ナイコンさん：01/12/31 17:30.net

使用機種：Windows95/98/Me/NT4.0/2000/XP（たぶん）
条件：WindowsScriptingHost（IE4以降に同梱）が動く環境
注意：以下のテキストを拡張子.vbsで保存して実行してください

FOR I=1 TO 10
FOR J=1 TO 10
A=A+"ｵﾏｴﾓﾅｰ"
NEXT
A=A+CHR(13)
NEXT
MSGBOX A,0,"ｵﾏｴﾓﾅｰ"

103 ：ナイコンさん：02/01/05 19:49.net

1000 PRINT"10 FOR I=1 TO 100
1010 PRINT"20 PRINT"ｵﾏｴﾓﾅｰ ";
1020 PRINT"30 NEXT
1030 PRINT"RUN
1040 PRINT"ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ
1050 PRINT" ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ
1060 PRINT" ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅ
1070 PRINT"ｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓ
1080 PRINT"ﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴ
1090 PRINT"ﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ｵﾏｴﾓﾅｰ ^C
1100 PRINT"Break in 20
1110 PRINT"Ok
1120 PRINT"■

104 ：大学生MSXユーザ：02/01/08 19:47.net

あけおめです。

新年一発目です。比較的オーソドックスな作りにしてみました。
使用機種：ＭＳＸ（多分ＭＳＸ２未満はダメ）

3 A=RND(-TIME)*20+1:D=RND(-TIME)*1
5 FORI=1TO20:LOCATE2,Y(I):FORJ=1TO5
2 FORI=1TO20:Y(I)=I:NEXT:FORI=1TO100
1 SCREEN0:WIDTH40:COLOR2,0,0:DIMY(20)
7 COLORIMOD15+1:NEXT:LOCATE0,21:COLOR2
4 B=RND(-TIME)*20+1:SWAPY(A),Y(B):NEXT
6 W=ATN(.1)^ATN(1):PRINT"ｵﾏｴﾓﾅｰ ";:NEXT

105 ：HITBITでｵﾏｴﾓﾅｰ発声練習：02/01/08 21:21.net

初挑戦。SONY HITBIT(MSX)にて。
auto
10 CLS:COLOR 15,1,1:PLAY "T120"
20 FOR I=1 TO 25
30 PRINT "ｵﾏｴﾓﾅｰ":PLAY "O3C16C8C16C4"
40 PRINT "ｵﾏｴﾓﾅｰ":PLAY "E16E8E16E4"
50 PRINT "ｵﾏｴﾓﾅｰ":PLAY "G16G8G16G4"
60 PRINT "ｵﾏｴﾓﾅｰ":PLAY "O4C16C8C16C4"
70 NEXT I
80 END
どうでしょうか。

106 ：105：02/01/08 21:47.net

クソプログラムですが手を加えました。（負荷によっては表示ズレます）
auto
10 CLS:COLOR 15,1,1:PLAY "T120"
20 FOR I=1 TO 25
30 PRINT "ｵ":PLAY "O3C16":PRINT "ﾏｴ":PLAY "C8":PRINT "ﾓ":PLAY "C16":PRINT "ﾅｰ":PLAY "C4"
40 PRINT "ｵ":PLAY "E16":PRINT "ﾏｴ":PLAY "E8":PRINT "ﾓ":PLAY "E16":PRINT "ﾅｰ":PLAY "E4"
50 PRINT "ｵ":PLAY "G16":PRINT "ﾏｴ":PLAY "G8":PRINT "ﾓ":PLAY "G16":PRINT "ﾅｰ":PLAY "G4"
60 PRINT "ｵ":PLAY "O4C16":PRINT "ﾏｴ":PLAY "C8":PRINT "ﾓ":PLAY "C16":PRINT "ﾅｰ":PLAY "C4"
70 NEXT I
80 END
どうでしょうか。

107 ：FMV：02/01/08 22:06.net

Active basic　N88互換
10 cls
20 x=int(rnd(1)*58):y=int(rnd(1)*20):i=i+1
30 locate x,y
40 print "ｵﾏｴﾓﾅｰ"
50 if i<100 then goto 20

目的：画面上に１００回「ｵﾏｴﾓﾅｰ」と表示させる。
10 print "１００回「ｵﾏｴﾓﾅｰ」"
以上

108 ：ナイコンさん：02/01/08 22:31.net

MZ-80 SP-5030 print文で複数出すのって;じゃなく,だったっけ？

10 READ A1$,A2$,A3$,A4$,A5$,B1$,B2$,B3$,B4$,B5$
20 READ C1$,C2$,C3$,C4$,C5$,D1$,D2$,D3$,D4$,D5$
30 READ E1$,E2$,E3$,E4$,E5$,F1$,F2$,F3$,F4$,F5$,CR$,UE$
40 FOR I=1 TO 100 : CURSOR INT(RND*9),INT(RND*19):
50 PRINT "C";A1$;CR$;A2$;CR$;A3$;CR$;A4$;CR$;A5$;UE$;
60 PRINT B1$;CR$;B2$;CR$;B3$;CR$;B4$;CR$;B4$;UE$;
70 PRINT C1$;CR$;C2$;CR$;C3$;CR$;C4$;CR$;C4$;UE$;
80 PRINT D1$;CR$;D2$;CR$;D3$;CR$;D4$;CR$;D4$;UE$;
90 PRINT E1$;CR$;E2$;CR$;E3$;CR$;E4$;CR$;E4$;UE$;
100 PRINT F1$;CR$;F2$;CR$;F3$;CR$;F4$:CR$;F4$:NEXT:END
110 DATA " @ ","@@@@@ "," @@ "," @ @ ","@ @ "
120 DATA "@@@@@ "," @ "," @ @ "," @ "," @ "
130 DATA "@@@@@ "," @ "," @ "," @ ","@@@@@ "
140 DATA "@@@@@ "," @ ","@@@@@ "," @ "," @@@ "
150 DATA " @ ","@@@@@ "," @ "," @ "," @ "
160 DATA " "," ","@@@@@ "," "," "
170 DATA "←←←←←←↓","↑↑↑↑↑"

109 ：ナイコンさん：02/01/08 22:35.net

>>107
Active basic使う場合は
負荷かけないとｵﾓﾛﾅｲ...

110 ：108：02/01/08 22:43.net

スペースつまった
110 DATA "　　　■　　","■■■■■ ","　　■■　　","　■　■　　","■　　　■　 "
120 DATA "■■■■■ ","　　　　■　","　■　■　　","　　■　　　","　　■　　　"
130 DATA "■■■■■ ","　　■　　　","　　■　　　","　　■　　　","■■■■■ "
140 DATA "■■■■■ ","　　■　　　","■■■■■　","　　■　　　","　　■■■　　"
150 DATA "　　■　　　","■■■■■ ","　　■　　　","　　■　　　","　■　　　　"
160 DATA "　　　　　　","　　　　　　","■■■■■ ","　　　　　　","　　　　　　"

50行目のCは反転の画面消去のやつ。170行目のはカーソル制御のやつ

111 ：105　>>ActiveBasic：02/01/08 22:57.net

音源つけて動かしてください。ちと修正しました。
何回も似たようなプログラム書いてスマソ。
10 CLS
20 FOR I=1 TO 25
30 PRINT "ｵ";:PLAY "O3C16":PRINT "ﾏｴ";:PLAY "C8":PRINT "ﾓ";:PLAY "C16":PRINT "ﾅｰ　";:PLAY "C4"
40 PRINT "ｵ";:PLAY "E16":PRINT "ﾏｴ";:PLAY "E8":PRINT "ﾓ";:PLAY "E16":PRINT "ﾅｰ　";:PLAY "E4"
50 PRINT "ｵ";:PLAY "G16":PRINT "ﾏｴ";:PLAY "G8":PRINT "ﾓ";:PLAY "G16":PRINT "ﾅｰ　";:PLAY "G4"
60 PRINT "ｵ";:PLAY "O4C16":PRINT "ﾏｴ";:PLAY "C8":PRINT "ﾓ";:PLAY "C16":PRINT "ﾅｰ":PLAY "C4"
70 NEXT I
80 END

112 ：&heart;：02/01/08 23:19.net

そういえば、CHR$なんてのもあったなぁ。
スクロールはこいつで指定すればいいと思われ。

113 ：&hearts：02/01/12 14:15.net

MS-BASICにしようや

114 ：大学生MSXユーザ：02/01/13 01:29.net

今回はさらに原点に戻ってみました。

動作環境：ほぼ全てのBASIC

1 LET A$ = "OMAEMONA- "
2 FOR I = 1 TO 100
3 PRINT A$;
4 NEXT I
5 END

115 ：ナイコンさん：02/01/15 18:27.net

あたらしいお題ほしい

116 ：ナイコンさん：02/01/15 21:12.net

10 SAVE "ｵﾏｴﾓﾅｰ"
20 FOR A=1 TO 100:PRINT "ｵﾏｴﾓﾅｰ":NEXT A
30 KILL "ｵﾏｴﾓﾅｰ"
40 CLS
50 NEW

117 ：ナイコンさん：02/01/15 21:16.net

10 FILES
20 INPUT"ﾛｰﾄﾞｼﾀｲ ﾌｧｲﾙﾒｲ ";A$
30 KILL A$
40 PRINT "ﾌｧｲﾙｶﾞ ﾐﾂｶﾘﾏｾﾝ"

118 ：ナイコンさん：02/01/16 00:34.net

１さん、あたらしいお題を発表してヨ。

119 ：大学生MSXユーザ：02/01/16 01:00.net

>>1さんは今年に入ってから書きこみ無いみたいだけど
・・・俺がお題出しても良い？>all

120 ：ナイコンさん：02/01/16 01:05.net

次のお題の前に大賞を決めてはおかぬか。

121 ：1=JOY ◆chesX68k ：02/01/16 07:50.net

それではエントリーを締め切って選考に入りたいと思います。発表はしばらく待て。
選考は勝手ながら独断でさせてもらうっす。（仕切り厨でスマソ）
次はちょっとテクニカルなお題を考えてるんで、期待してて。

122 ：ナイコンさん：02/01/16 10:18.net

>>1
またBASICでよろしく。

123 ：ナイコンさん：02/01/16 14:30.net

テクニカルなお題もいいけど
くっだらないゲームもきぼーん

124 ：ナイコンさん：02/01/16 19:45.net

>>123
テクニカルなお題をくだらないゲームにするのが腕の見せ所。
しかしテクニカルなお題は俺の脳内BASICインタプリタが処理できないかも(w

125 ：ナイコンさん：02/01/17 00:44.net

審査の間、ワイデスのダンスをお楽しみください

100 WIDTH 40,25:CLS
110 X=18
120 RESTORE
130 READ A
140 IF A=0 THEN 120
150 IF A=4 THEN GOSUB 200
160 IF A=6 THEN GOSUB 300
170 FOR I=0 TO 500:NEXT
180 GOTO 130
200 X=X-1
210 LOCATE X,10:PRINT " ＼●　　";
220 LOCATE X,11:PRINT "　　■＞　";
230 LOCATE X,12:PRINT "　＜　＼　";
240 RETURN
300 X=X+1
310 LOCATE X,10:PRINT "　　 ●／　";
320 LOCATE X,11:PRINT "　＜■　　";
330 LOCATE X,12:PRINT "　／　＞　";
340 RETURN
1000 DATA 4,6,4,6,4,4,4,4,6,6,6,6,0

126 ：大学生MSXユーザ：02/01/17 03:55.net

>>125
MSXに移植してみました。
一部簡単には表現不可能な所があったので独自の修正を施しています。
TurboRの高速モード対応（藁

100 SCREEN 0:WIDTH 40:CLS
110 X=18
120 RESTORE
130 READ A
140 IF A=0 THEN 120
150 IF A=4 THEN GOSUB 200
160 IF A=6 THEN GOSUB 300
170 TIME=0:FOR I=0 TO 10:I=TIME:NEXT
180 GOTO 130
200 X=X-1
210 LOCATE X,10:PRINT " ┐●　　";
220 LOCATE X,11:PRINT "　　ロ＞　";
230 LOCATE X,12:PRINT "　＜　└　";
240 RETURN
300 X=X+1
310 LOCATE X,10:PRINT "　　 ●┌　";
320 LOCATE X,11:PRINT "　＜ロ　　";
330 LOCATE X,12:PRINT "　┘　＞　";
340 RETURN
1000 DATA 4,6,4,6,4,4,4,4,6,6,6,6,0

127 ：JOY ◆chesX68k ：02/01/17 21:56.net

お待たせしました。
第１回昔のＰＣ板杯プログラムコンテストの発表です。
実行可能な物は全て実行してみて、実行できないのは脳内トレースして、
プログラムのアルゴリズムも吟味したうえで決めてみました。


大賞：ナイコンさん >>25
http://pc.2ch.net/test/read.cgi/i4004/1008847300/25
発表直後はスレの住人を震撼させた、まさに衝撃の作品。
誰もが予想だにしなかった方法で課題を実現させている。逆転的発想が大賞
受賞の決め手であり、受賞に関して疑いの余地は無いだろう。
「これをやられちゃったら、このあと何も出せないよ！」という声も・・・・・・。
ほぼ全機種対応という脅威的な汎用性も持っている。
素晴らしい。感動した。


次点：ナイコンさん >>88-89
http://pc.2ch.net/test/read.cgi/i4004/1008847300/88-89
ゲーム化してエントリーされた作品はいくつかあったが、課題のルールを
守ったうえで、見た目にも分かりやすく楽しかった作品がこれ。
１００回表示させるのを前提に考えられた画面レイアウトも良い感じ。
「大金もち」「大びんぼう」という言葉のセンスも、当時を思い出させる。
一発系の>>25が無ければ、間違いなく大賞になっていただろう。惜しい。


次点：ナイコンさん >>77
http://pc.2ch.net/test/read.cgi/i4004/1008847300/77
人工無能という崇高な題材に挑戦した作品。
見事に突っ込みだけでスレッドを１本dat行きにさせてしまっている。
惜しむらくは、「オマエモナー」がスレの前半で１００回表示しきって
してしまうことと、突っ込み言葉のバリエーション不足。
スレ全体にまんべんなく散りばめられていれば、なお良かったと思われ。


特別賞：大学生MSXユーザさん >>3,>>23他
スレ立ち上げ当初からエントリー受け付けギリギリまで作品を提供し続け、
このコンテストを盛り上げた功績は大きい。特別賞を進呈したい。
ハンドル通り、一貫してＭＳＸのプログラムにこだわる職人気質。
色々なアプローチで正統派＆技術派な作品を提供してくれた。
現役の（？）大学生でＭＳＸを使っているというのもポイント高し。


（総評）
当時、覚えたてのＢＡＳＩＣで組んだ「くだらね〜〜ヨ！」的なノリの
プログラムコンテストをやってみたいと思ったのが始まりなんだが、
みんな付き合って遊んでくれてありがとさん。

今でこそ職業プログラマやってるが、ルーツはこれだろ！みたいな、
そういうのは忘れずにいたいもんだな・・・・・と改めて思たよ。

もっと色々な機種のＢＡＳＩＣが見れるかと思ったけど、予想以上に
Ｎ系が多かったな。ぴゅう太の日本語ベーシックは出てくるだろ！？と
思っていたんだが・・・・・・。お題が悪かったか？。正直スマン。
ワイデスネタも出ると踏んでたが・・・・。あ、最後に出たね。

やはり、昔のＰＣ板らしくＢＡＳＩＣ限定のほうが楽しいな。
機種毎に方言があるところが、また楽しい。
次回もまたヨロシク！！

128 ：JOY ◆chesX68k ：02/01/17 21:57.net

ということで、大賞を決めてみた。予想通りだったかな？？。

新しいお題のネタはあったんだが、>>119で 大学生MSXユーザさんが
お題を出したいようだったので、彼に一任することにしたいけど、どう？。
ま、特別賞の御褒美って事で。特に反論がなければ、そうしよう。

>>123で「くっだらないゲーム」という希望もあるので、そのことも考慮して
決めちゃってください＞大学生MSXユーザさん

この後は、第２回として新スレを立てるかどうか？を このままこのスレで
議論しつつ、しばらくは第１回の感想などでマターリしようよ。
第２回を新スレにするなら、このスレは sage進行専用の方向で。


>>119
＞ １さんは今年に入ってから書きこみ無いみたいだけど
最近は P/ECEのほうに凝っててなー。そっちのコンテストに向けてプログラムに
萌えているよ・・・・って、このスレとは直接関係無いから sageとく。

129 ：俺も参加する：02/01/18 00:07.net

１０　NEW

130 ：大学生MSXユーザ ◆Ym1dK0rg ：02/01/18 00:36.net

ども、特別賞頂いた大学生MSXユーザです。

>>1=JOY ◆chesX68kさん了解しました。
さっそく第2回のお題と>>1用の文章考えてみたんで評価頼みます。>all

＝＝＝ここから
毎年恒例となった 第２回昔のＰＣ板杯ﾌﾟﾛｸﾞﾗﾑｺﾝﾃｽﾄを開催するヨ！
かつてやった（であろう）ｸﾀﾞﾗﾈｰ!!プログラムや ｸﾀﾞﾗﾈｰ!!テクニックを
再びここで披露して下さい。

目的：２ちゃんねる系キャラクター（モナー、ギコ猫、etc...）
　　　を使ったくだらないミニゲームを作る。

使用機種：不問

使用言語：ＢＡＳＩＣ限定（各機種の方言の使用は可）
　　　　　また、コードがBASICのみで書かれているならばマシン語の使用も可とします。

条件：プログラムコードが長くならないように注意。
　　　（省略されました・・全てを読むにはここを押してください）が
　　　出てしまったら、そのエントリーは無効。

評価：今度は投票で決めたいと思います。

投票方法：(ﾟ∀ﾟ)ｲｲ！と思ったプログラムのスレ番号をxxxとして、
　　　　　名前欄には適当なトリップを付けて、本文には
　　　　　1行目に「投票xxx」（xxxは半角数字で）と書き、
　　　　　2行目以降には感想を書いて（←これは無くても良い）
　　　　　レスして下さい。このフォーマットから外れたレスは無効票とします。
　　　　　なお、一人2票まで投票可能とします。

　　　　　前スレ同様、綺麗なソースやアルゴリズムだけではなく、
　　　　　実行したときの芸術性などを考慮した上で評価してください。

注意：半角空白は連続して書くと1つに纏められて見えてしまう為、
　　　&nbsp;又は全角空白に置き換えてレスして下さい。
　　　また、機種依存文字は出来るだけ似た字に置き換えて書いた上で注釈を入れて下さい。

エントリーする人は、動作機種を（ものによっては何ＢＡＳＩＣかも）明記して下さい。

エントリー終了と投票開始の時間はこの>>1の投稿日から丁度30日経った”瞬間”です。

エントリーに対するレスなんかは随時大いにしちゃってOK！もりageて行こう！
ﾋﾞｸｰﾘするようなヤツ期待してます！
＝＝＝ここまで

131 ：ナイコンさん：02/01/18 00:42.net

>>130
「ルール詳細は>>2参照」ってのをきぼーん

132 ：ナイコンさん：02/01/18 02:12.net

>>128
とりあえず新スレは見合わせた方がいいと思う。まだ100ちょっとしか使ってないわけだし。
ただ、そうなると現在のレギュレーションがわかりにくくなるという難点があるので、
定期的にレギュレーションにリンクを貼る等の行為が必要となるかも。

>>130
モナーやギコ猫のＡＡを作れない機種も出て来るかと思うので、
単純に「くだらないミニゲームを作る」でよいかも。

使用言語の「コードがBASICのみで書かれているならばマシン語の使用も可とします」は
ちょっとニヤリとさせられた。

133 ：ナイコンさん：02/01/18 02:19.net

もうちょっと目的を限定しないとｺﾝﾃｽﾄになんないよ

134 ：ナイコンさん：02/01/18 02:27.net

短いプログラムしか載せられないので、ワンキーゲームとかどう？

135 ：名無しさん：02/01/18 03:14.net

8bit機だと表示できる文字種が少なくてAAは厳しいよぉ。
そのへん何とかならんかね。

136 ：大学生MSXユーザ ◆Ym1dK0rg ：02/01/18 03:35.net

>>131さん
確かにそのほうが良いと思います。

>>132,>>135さん
確かに>>125を移植したときも必要な文字無くて困ったんで。
MSXの様に文字の形を再定義出来るマシンは良いとして
MZ-700みたいに固定されてるマシンもあるし。
２ちゃんねる系キャラ限定は解除ですかね。

>>134さん
それ(ﾟ∀ﾟ)ｲｲ！です。

で、以上を踏まえて考えてみた修正案（>>130からの差分）
・文全体を>>2に移動。
・目的をくだらないワンキーミニゲームに偏光^H^H変更。
・注意：の2行目先頭に誤植？「又は」→「＆nbsp;を半角で、又は」
・（新ｽﾚ立てる場合）このｽﾚへのリンクを追加。

問題点
・本当に新ｽﾚを立てるか？
・ｽﾚの管理
（俺今4年生なんです。暫くしたら卒論が・・・）

あと、あんましこのスレと関係無いんだけど（ｗ
各機種固有の命令の使い方間違ってるのとか合ったりしたんで、
「昔のPCのBASICの文法を勝手に教えるｽﾚ」
とか立てたら人来ると思います？

というわけで継続して意見レスｷﾎﾞｰﾝ。

137 ：ナイコンさん：02/01/19 11:37.net

誰か>>25をぴゅう太に移植してくれ。

>>130、136
投票にこだわる必要もないと思うなあ。
ＭＳＸユーザ氏の一存で決めても文句でないと思うし。
少なくとも投票にトリップは不要でしょう。

BASICの文法を勝手に教えるスレは需要はあるとおもう。
BASICの移植に関する指針とかも話題に加えていいかも。
もし立てたらこのスレからのリンクは必須だね。
個人的には欲しい。情報提供はできないけど(w

138 ：ナイコンさん：02/01/20 02:53.net

目指せ「昔のPC板のベーマガ」だな。
乗り遅れたが、一応書いておく

PC-6001 N60-BASIC
10 ? "ｵﾏｴﾓﾅｰ"
20 C=C+1:IF C=100 THEN EXEC 0
30 GOTO 10

139 ：大学生MSXユーザ ◆Ym1dK0rg ：02/01/28 02:53.net

スレ放置してしまってすいませんでした。
今週は風邪と期末テストでダウンしててまともにネット繋げてませんでした。
次スレの文案を作ってみました。
それと、次スレの管理は>>1= JOY ◆chesX68kさんに頼みたいんですけど良いですか？

REM あと3周間程で卒論の締め切りという罠 =ﾛo_

次スレ>>1
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
毎年恒例となった 第２回昔のＰＣ板杯ﾌﾟﾛｸﾞﾗﾑｺﾝﾃｽﾄを開催するヨ！
かつてやった（であろう）ｸﾀﾞﾗﾈｰ!!プログラムや ｸﾀﾞﾗﾈｰ!!テクニックを
再びここで披露して下さい。

詳しくは>>2で。

前スレ　http://pc.2ch.net/test/read.cgi/i4004/1008847300/
※）前スレはこのスレに関連した雑談用途に使用してください。


次スレ>>2
＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝＝
目的：くだらないワンキーミニゲームを作る。

使用機種：不問

使用言語：ＢＡＳＩＣ限定（各機種の方言の使用は可）
　　　　　また、コードがBASICのみで書かれているならばマシン語の使用も可とします。

条件：プログラムコードが長くならないように注意。
　　　（省略されました・・全てを読むにはここを押してください）が
　　　出てしまったら、そのエントリーは無効。

評価：前スレとは違って今度は投票で決めたいと思います。

投票方法：(ﾟ∀ﾟ)ｲｲ！と思ったプログラムのスレ番号をxxxとyyyとして、本文に
　　　　　1行目に「投票xxx+yyy」（xxx+yyyは半角数字で）と書き（1票のみの場合は「投票xxx」と書く）、
　　　　　2行目以降には感想を書いて（←これは無くても良い）
　　　　　レスして下さい。このフォーマットから外れたレスは無効票とします。
　　　　　なお、上記の通り一人2票まで投票可能とします。

　　　　　投票締め切りは900まで又は最初の作品が出てから丁度30日までとします。

　　　　　前スレ同様、綺麗なソースやアルゴリズムだけではなく、
　　　　　実行したときの芸術性などを考慮した上で評価してください。

注意：半角空白は連続して書くと1つに纏められて見えてしまう為、
　　　＆nbsp;を半角にしたもの、又は全角空白に置き換えてレスして下さい。
　　　また、機種依存の特殊文字は出来るだけ似た字に置き換えて書いた上で注釈を入れて下さい。

エントリーする人は、動作機種を（ものによっては何ＢＡＳＩＣかも）明記して下さい。

エントリー終了と投票開始の時間はこの>>1の投稿日から丁度30日経った”瞬間”です。

エントリーに対するレスなんかは随時大いにしちゃってOK！もりageて行こう！
ﾋﾞｸｰﾘするようなヤツ期待してます！

140 ：大学生MSXユーザ＠学校：02/01/28 11:13.net

あぅ。age忘れ。

141 ：ナイコンさん：02/01/28 13:48.net

このスレ最高。
っつーか、漏れも未だにポケコン使って子供の遊戯王カード用計算プログラムとかBASICで作ってるし。
次スレはエントリーすんぞ〜。

142 ：ナイコンさん：02/01/28 16:08.net

みんなでコレ使ってプログラム持ち寄らねえ？
http://www.sagami.ne.jp/tadaka/99Basic/